To elaborate on this achievement, earlier this year was the setup of a homebrew CCTV solution using an array of Raspberry Pi’s with cameras, and a VM Cent OS server acting as a PVR host. A surplus Pi W Zero was pointed at the hills and used as a time-lapse experiment.

The real achievement is that since its conception in early June, it has been stable enough to run in the background, capturing footage for such an occasion.

So here I present my latest time-lapse, a split screen video on the difference between a June day and a December day:

With time a solution also brings some observations and learning opportunities that would have been hard to imagine on conception:

Storage Capacity: In hindsight it was wise to start this project in June and during the summer solstice of the northern hemisphere. The maximised daylight hours created the most capture data stored to disk; therefore, the retention times of footage could be set to ensure the disk does not reach capacity.

While this works for MotionEye’s capture settings, the time-lapse script has been able to run without capacity constraints, so the 83GB (on a 3TB disk) will need to be moved / deleted off the disk as the nights grow longer to avoid exhaustion of storage space.

Camera Movement: During its conception, an elegant solution to create a makeshift mount for the camera was to fashion some bell wire (single core insulated wire) from the mount points of the Pi to the mount points of the camera, twisted in-between to add rigidity.

What I didn’t account for was the effect heat would have on twisted wire, this was apparent in the summer but seemed organic as the movement was in line with the temperature fluctuations of a normal day. However unforeseen was the winter and with that the part my central heating and radiators would manipulate the cameras position.

The combination of the radiator below the camera and the heating set on a timer resulted in large skews of the camera’s position, to the point where you could tell when the heating was on and off during the day. As a result, the footage used for winter was recorded while I wasn’t home and so the heating was off.

Something I wanted to capture is a time-lapse of of summer and winter from the same perspective, in order to see the difference between the two polar seasons in terms of sunlight.

Now with a year’s worth of capture and as a tribute to the reliability of the code, I thought to quickly splice together a June and December time lapse video:

Its interesting to see how the webcam when left at the default settings interprets light values over a sustained period of time. As even in the summer it will get as dark as the winter night at some point, I thought of this as a natural reset point for the cam’s light values.

Choosing a similar weather conditions at both ends of the daylight spectrum (23/06 and 19/12) the camera seemingly registers a different light strength.

Anyways it is still an interesting watch regardless of the date its being viewed at, hope you enjoy, and wishing you a happy new year!

I also dabbled in the past with time lapse videos, however this was a more manual process with images capturing to a folder, then personally loading them into Windows Movie Maker to create the video. With the tedium of creating the videos, the software I used for capturing (YAWCam) would hang after a few weeks constant running, not to mention without upkeep, the hundreds of thousands of image files populating the hard drive.

As a project it was time to combine the learnings from these and create an automated time lapse video creator, a program that would capture images, then create a 5-minute video that contains the days’ footage, and finish by deleting the temporary images to leave just the days video.

As with the CCTV project, a batch file will be used to create the process as what I need can be achieved by DOS commands plus it’s able to be called by Windows Task Scheduler. This time I will have the advantage of using an IP camera instead of USB, so negating the need for software to capture images, however the WGet utility is needed to download and save the images locally. Also the script will invoke FFMpeg to convert the images to video at the end of the day.

Setup

Getting started, place the WGet utility in the System32 folder so it can be called from dos without specifying a path. Then create this folder hierarchy on the root of C:\ drive:

Here’s the code for capture.bat, I placed this in the Data folder with ffmpeg.exe for neatness:

@echo off
::SET DATE TO A VARIABLE
set todaydate=%date:~-4%-%date:~3,2%-%date:~0,2%
::RESET COUNTER TO ZERO
set counter=100000

::CREATE TODAYS FOLDER AND NAVIGATE TO IT
echo Creating Folder…
c:
cd \cam\Data\temp\
md %todaydate%
cd %todaydate%
::LOOP START
echo Capturing Images…
:capture
::GET IMAGE FROM WEBCAM CGI
wget -q http://xxx.xxx.xxx.xxx/image/jpeg.cgi

::RENAME FILE USING COUNTER
ren jpeg.cgi image%counter%.jpg

::INCREMENT COUNTER BY ONE
set /a counter=counter+1

::SET TIME TO VARIABLE
set hour=%time:~0,2%
if “%hour:~0,1%” == ” ” set hour=0%hour:~1,1%
set min=%time:~3,2%
if “%min:~0,1%” == ” ” set min=0%min:~1,1%
set secs=%time:~6,2%
if “%secs:~0,1%” == ” ” set secs=0%secs:~1,1%
set thetime=%hour%%min%%secs%

::TIME BEFORE NEXT IMAGE
timeout /t 3 >nul

::CHECK ITS NOT END OF DAY
if %thetime% LSS 120600 (
goto capture
) else (
::START CONVERTING VIDEO
echo Processing Timelapse Video…
“C:\cam\Data\ffmpeg.exe” -loglevel quiet -i C:\cam\Data\temp\%todaydate%\image1%%05d.jpg -r 28 -c:v libx264 C:\cam\Video\%todaydate%.mp4
echo Deleting temp files…
::TIME DELAY TO ALLOW PROCESS TO CLOSE
timeout /t 10 >nul
::CHANGE DIRECTORY OUT OF FOLDER TO BE DELETED THEN DELETE TEMP FILE
cd \cam\Data\temp\
RD /S /Q “C:\cam\Data\temp\%todaydate%”
)
echo Process Complete

Next is to create a Scheduled Task in Windows to launch the program each day at midnight, this process varies by system but ensure that user privileges are high enough to write and execute on disk.

I found Windows Server 2012 R2 had a lot more options over Server 2003, so I set the task to run when even when not logged on, to run hidden, and now the time can be specified to the second, so chose to start task at 00:00:03 to make sure the date is correct.

Notes

Hopefully the annotation will be helpful enough if you would like to apply your own tweaks, but here are some of notes about the issues I faced when creating the script:

• Originally the images named with a timestamp, however FFMpeg requires images to be sequentially numbered to create the slideshow.
• The counter was set at 000000, but on the first loop the arithmetic to increase the counter changed the value to 1, so lines were added to include the leading zeros
• The leading zeros meant that the machine was reading the number as an octet, so on the 8^th loop the counter reset to 000001, as a workaround a leading 1 was added to the counter.
• Capturing images every 10 seconds equates to 8640 images a day, the counter it set to five decimals to ensure no looping of counter numbers.
• In addition to storing the date as a variable to allow multiple calls, it allows the program to keep the same date after time moves into the next day. Since the video conversion starts at 23:59 each day its very likely the process will move into the next day when temp files are deleted.
• Initially the time variables were inside the IF statement, but learned that the variable with an IF statement are created when the program is parsed, not run, therefore would not update.
• However, the time needs to be in the loop to update before the IF statement is reached, the date is purposely kept out to it retains the value set at the start of the script.
• While statements don’t really exist in batch files, so goto and If commands were used to create a crude while loop.

I dare not say that the code is perfect, or if the choice of programming language is suitable, the aspiration would be to create a self contained executable with a configuration file to specify target folders, change finish time and time between image captures. But for now it’s doing the job just fine.

Update

Since creating the program I’ve reused parts of the code to create a preview program that compiles the images taken so far that day into a video, without deleting any files. Here’s the code, again, save as a bat file and double click to run immediately.

@echo off

echo Establishing todays date…
::FIND TODAYS DATE TO ESTABLISH FOLDER NAME
set todaydate=%date:~-4%-%date:~3,2%-%date:~0,2%

::FIND TIME TO CREATE FILENAME VARIABLE
set hour=%time:~0,2%
if “%hour:~0,1%” == ” ” set hour=0%hour:~1,1%
set min=%time:~3,2%
if “%min:~0,1%” == ” ” set min=0%min:~1,1%
set secs=%time:~6,2%
if “%secs:~0,1%” == ” ” set secs=0%secs:~1,1%
set thetime=%hour%%min%%secs%

echo Locating temp files…
::NAVIGATE TO IMAGE FOLDER
C:
cd \cam\Data\temp\
cd %todaydate%

echo Creating preview video
::CREATE VIDEO AND ADD PREVIEW IN FILENAME TO AVOID DUPLICATE FILENAMES
“C:\cam\Data\ffmpeg.exe” -loglevel quiet -i C:\cam\Data\temp\%todaydate%\image1%%05d.jpg -r 28 -c:v libx264 V:\Timelapse\Video\preview-%todaydate%-%thetime%.mp4

echo Complete